首先，设置热点的模式，ssid，password，使用这条命令：

netsh wlan set hostednetwork mode=allow ssid=xxx key=xxx

之后开启热点：

netsh wlan start hostednetwork

这时，打开更改适配器设置，多出来一个虚拟网卡

打开已连接网络的有线网卡的属性，打开共享页，在“请选一个专用网络连接”中选择刚才多出来的虚拟网卡

将“允许其他网络用户通过此计算机的Internet连接在连接”打钩。这样，一个由虚拟网卡设置的WiFi热点就生成了。

既然可以开启，就需要停止，用这条命令：

netsh wlan stop hostednetwork

但开热点毕竟不常用，时间长了命令可能记不住了，不如写个批处理吧：

echo off
title Windows WIFI Ad Hot Setting By:otuki
color 1E
:main
cls
echo.
echo =========================================
echo            WIFI Ad Hot Setting
echo                 By:otuki
echo =========================================
echo.
echo.            1 - show hostednetwork
echo.            2 - start hostednetwork
echo.            3 - stop hostednetwork
echo.            4 - set hostednetwork
echo.            0 - exit
echo.-----------------------------------------------------------
echo.          Chioce 4 for the first run     
echo.          return to read document
echo.          http://otuki.top
set input=
set /p input=[please choice and press "enter"]:
if /i '%input%'=='1' goto show
if /i '%input%'=='2' goto start
if /i '%input%'=='3' goto stop
if /i '%input%'=='4' goto change
if /i '%input%'=='0' goto end
cls
echo.
pause
goto main

:end
set ssid=
set key=
exit

:show
cls
echo hostednetwork status:
echo.
netsh wlan show hostednetwork
echo.
pause
goto main

:start
cls
echo start hostednetwork
echo.
netsh wlan start hostednetwork
echo.
pause
goto show

:stop
cls
echo stop hostednetwork
echo.
netsh wlan stop hostednetwork
echo.
pause
goto show

:change
cls
echo set hostednetwork(SSID/KEY)
echo.
netsh wlan stop hostednetwork
echo.
set ssid=
set /p ssid=ssid:
echo.
set key=
set /p key=key(more than 8 characters):
echo.
netsh wlan set hostednetwork mode=allow ssid=%ssid% key=%key%
pause
goto start

管理员身份运行批处理代码，先输入4设置ssid和password，之后自动开启，如果第一次使用还需要到更改适配器设置中设置一下。输入1查看当前状态，包括连接数等信息，输入3停止热点，输入4清空ssid和paasword并退出。